#1 05.09.06 13:48
Dual program: C or PostScript!
Укроп написал(а):
/* % Dual program: C or PostScript!
% Ned Batchelder
%
{pop}/,{}/={}/"{}/+{}/;{pop}/-{moveto}/printf{show}/return{showpage}9{def}repeat
( */
# include <stdio.h>
# include <string.h>
/* ) */char count , def = 0 ;
/* */main()
{
char * /* */Courier = " findfont " + 36 , scalefont = 0 ;
char * setfont = "(Hello, world!)" + 0 * 100 + 0 * 100 - 0 ;
printf("%.*s\n", strlen(setfont)-2, setfont+1);
return ;
}
char * exec ;
Это не я бляяя...
Offline
#2 05.09.06 13:50
Re: Dual program: C or PostScript!
Укроп написал(а):
программка которая печатает собственный исходник
; RiXtA's SELF - DISASSEMBLER
; anno domine 2000
; supported instructions are (in alphabetical order):
; ADD AND CMP INT JNL JNZ MOV RET ROR
[org 100h]
[segment .text]
mov ch,0
int 10h
MAIN
CYK mov bh,1
mov bl,ch
mov dh,[bx]
mov al,dh
add al,16
and al,248-128
add cl,bh
jnz CYK
mov bl,TAB-1
mov cl,3
ror al,cl
add bl,al
add bl,al
add bl,al
add dl,bh
jnz CYK
add ah,bh
jnz CYK
mov ah,2
mov dl,10
int 21h
mov dl,13
mov cl,252
CYK2
int 21h
add bl,bh
VYPIS mov dl,[bx]
add cl,bh
jnz CYK2
mov dl,9
int 21h
mov cl,dh
mov al,dh
and al,248
cmp al,176
jnz OBS4
REGPRN
mov al,0CCh
ror al,cl
and al,3
mov dl,'a'
add dl,al
int 21h
mov al,cl
and al,4
mov dl,'l'
sub dl,al
int 21h
cmp ah,dh
jnz OBS5
NN_INC add ch,bh
NN
mov al,ch
cmp al,SEQR-256
jnz MAIN
mov ah,0
mov al,3
int 10h
KONCI ret
OBS3 cmp al,0
jnz NN
jnl REGPRN
OBS5 mov dl,','
int 21h
mov al,5
mov bl,ZTEXT-256
cmp dh,bh
jnz OBS16
mov cl,251
jnl VYPIS
OBS16 and dh,dh
jnz OBS2
add dh,ah
SPR_SPC
mov al,cl
mov cl,3
ror al,cl
mov cl,al
jnz REGPRN
OBS4
mov bl,5
and dh,bl
mov al,dh
cmp al,4
jnz OBS2
mov cl,8
jnl REGPRN
OBS2
add ch,bh
mov dl,138
cmp cl,dl
mov bl,ch
mov cl,[bx]
jnz OBS15
add dh,bh
jnz SPR_SPC
OBS15 cmp al,5
jnz OBS3
NUMPRN mov dh,254
NUMPR1 mov al,cl
mov cl,4
ror al,cl
mov cl,al
N2
and al,15
add al,55
cmp al,65
jnl OBS6
add al,256-7
OBS6 mov dl,al
int 21h
add dh,bh
jnz NUMPR1
jnl NN_INC
SEQR
TAB
db "jnz"
db "jnl"
db "add"
db "mov"
ZTEXT db "[bx]"
db "RX"
db "and"
db "sub"
db "mov"
db "cmp"
db "ret"
db "int"
db "ror"
Это не я бляяя...
Offline
#3 05.09.06 13:51
Re: Dual program: C or PostScript!
Укроп написал(а):
знаменитый полет в трехмерной трубе в 256 байт
; (▄) ( ) ▄ ) ( ) 256b intro by baze/3SC for Syndeecate 2001 use NASM to
; ▀ ▀ ▄ ▄ loveC: thanks, Serzh: eat my socks dude ;] compile the
; ( ) ( ) ( ) ( ) e-mail: baze@stonline.sk, web: www.3SC.sk source code
[org 100h]
[segment .text]
SCREEN equ 160
PIXBUF equ 204h
mov al,13h
int 10h
push word 0A000h
pop es
mov ax,cs
add ah,10h
mov fs,ax
xor cx,cx
PAL1 mov dx,3C8h
mov ax,cx
out dx,al
inc dx
sar al,1
js PAL2
out dx,al
mul al
shr ax,6
out dx,al
PAL2 mov al,0
out dx,al
jns PAL3
sub al,cl
shr al,1
out dx,al
shr al,1
out dx,al
PAL3 mov bx,cx
mov [fs:bx],bl
loop PAL1
TEX mov bx,cx
add ax,cx
rol ax,cl
mov dh,al
sar dh,5
adc dl,dh
adc dl,[fs:bx+255]
shr dl,1
mov [fs:bx],dl
not bh
mov [fs:bx],dl
loop TEX
fninit
fldz
MAIN add bh,8
mov di,PIXBUF
fadd dword [byte di-PIXBUF+TEXUV-4]
push di
mov dx,-80
TUBEY mov bp,-160
TUBEX mov si,TEXUV
fild word [byte si-TEXUV+EYE]
mov [si],bp
fild word [si]
mov [si],dx
fild word [si]
mov cl,2
ROTATE fld st3
fsincos
fld st2
fmul st0,st1
fld st4
fmul st0,st3
fsubp st1,st0
fxch st0,st3
fmulp st2,st0
fmulp st3,st0
faddp st2,st0
fxch st0,st2
loop ROTATE
fld st1
fmul st0,st0
fld st1
fmul st0,st0
faddp st1,st0
fsqrt
fdivp st3,st0
fpatan
fimul word [si-4]
fistp word [si]
fimul word [si-4]
fistp word [si+1]
mov si,[si]
lea ax,[bx+si]
add al,ah
and al,64
mov al,-5
jz STORE
shl si,2
lea ax,[bx+si]
sub al,ah
mov al,-16
jns STORE
shl si,1
mov al,-48
STORE add al,[fs:bx+si]
add [di],al
inc di
inc bp
cmp bp,160
EYE equ $-2
jnz TUBEX
inc dx
cmp dx,byte 80
jnz TUBEY
pop si
mov di,(100-SCREEN/2)*320
mov ch,(SCREEN/2)*320/256
rep movsw
mov ch,SCREEN*320/256
BLUR dec si
sar byte [si],2
loop BLUR
in al,60h
cbw
dec ax
jnz near MAIN
mov al,03h
int 10h
db 41,0,0C3h,3Ch
TEXUV db "baze"
Это не я бляяя...
Offline
